Android持续集成:Jenkins+Gradle+360加固+多渠道打包

发表于:2018-5-22 09:40  作者:Wang_Yi   来源:简书

字体: | 上一篇 | 下一篇 |我要投稿 | 推荐标签: 软件测试工具 jenkins 持续集成 集成测试

  首先说下我们项目的对于打包的需求,这里只针对发布正式环境的包。
  项目的代码放在Gitlab,需要打包的应用市场有十多个,apk都需要使用360加固,打包的工作由开发完成,然后将所有市场的apk文件压缩成一个zip文件发给市场的同事上线。最初的流程是由开发用AS打包后手动的进行加固,然后每次发布光打包-加固-修改apk文件名+发邮件这个流程都得花上半个小时以上。为了提高效率,所以我决定使用gradle+jenkins来完成这个任务。
  其实这样的文章挺多的,但是别人的需求总是不太能完美的解决我的问题,所以我自己通过gradle写了个task来解决我的需求。
  Gradle脚本
  一. 在Project下新建一个目录reinforce,将360加固相关文件导入
  channel这个目录是我自己创建的,里面保存了多渠道打包的配置模板
  二. 修改Android Studio生成apk文件名
  build.gradle中添加配置:
android.applicationVariants.all { variant ->
variant.outputs.all {
outputFileName = "pccb-v" + defaultConfig.versionName + "-" +
variant.productFlavors[0].name + "-" + variant.buildType.name + ".apk"
}
}
  pccb是我们项目名,生成的apk文件名pccb-v3.2.0-vivo-release.apk这种形式,后面从这个文件名中获取渠道和版本信息。
  三. 创建gradle脚本文件app/pack-release.gradle
  我创建了一个task packageRelease,这个task依赖assembleRelease,assembleRelease执行完成后会执行packageRelease的doLast方法。
  packageRelease的执行流程:
  1.从outputs/apk/xx/release中找出assembleRelease生成的所有apk
  我这里有4个渠道,所以最终生成了4个apk文件。理论上来说我们在打多渠道包的时候,可以使用360加固的多渠道打包功能由一个包就可以生成N个渠道包,但是我这里有点特殊的是我们十多个渠道的app名字并不是一样的,总共有4个app名,每个对应几个渠道。360加固只能修改AndroidManifest.xml中meta-data标签中的值,所以我这里必须为每个app名生成一个apk文件,并且在reinforce/channel中创建了4个多渠道打包模板。
  2. 创建一个保存加固后的apk目录:
  根据版本号创建目录,build/outputs/release/pccb-x.x.x
  3. 将4个原始的apk进行360加固,生成多个渠道的apk,自动签名
  4. 删除加固后生成的temp.apk和jiagu_sign.apk结尾的文件,保留渠道名+_sign.apk结尾的文件
  5. 根据需要修改保留的apk的文件名
  6. 压缩pccb-x.x.x文件夹,生成pccb-x.x.x.zip
  pack-release.gradle代码:
import java.util.zip.ZipEntry
import java.util.zip.ZipOutputStream
ext {
BASE = "../reinforce/"
JAR = BASE + "jiagu.jar"
NAME = ""//360加固账号
PASSWORD = ""//360加固密码
KEY_PATH = "" //密钥路径
KEY_PASSWORD = "" //密钥密码
ALIAS = "" //密钥别名
ALIAS_PASSWORD = "" //别名密码
OUTPUT_PATH = "build/outputs/release/" //加固后所有apk的保存路径
CHANNEL_CONFIG = BASE + "channel/"//保存渠道配置
}
class ApkFile {
String channel
File file
}
/**
* 查找所有apk
* @param buildType release 或者 debug
* @return ArrayList <ApkFile>
*/
def findApkFiles(String buildType) {
println "findApkFiles buildType: " + buildType
File apkDir = new File("build/outputs/apk")
File[] channelDirs = apkDir.listFiles()
List<ApkFile> apkFiles = new ArrayList<>()
for (int i = 0; i < channelDirs.length; i++) {
File channelDir = channelDirs[i]
ApkFile apkFile = new ApkFile()
apkFile.channel = channelDir.name
File[] files = new File(channelDir, "/" + buildType).listFiles()
if (files == null || files.length == 0) {
continue
}
File lastFile = files[files.length - 1]
if (!lastFile.name.endsWith(".apk")) {
continue
}
apkFile.file = lastFile
apkFiles.add(apkFile)
}
return apkFiles
}
/**
* 360加固
* @param apk 加固的原始apk File
* @param outputPath 输出目录
* @param channel 原始渠道(baidu,yyb,...)
*/
def reinforce(apk, outputPath, channel) {
println "reinforce apk:" + apk
//jiagu.db中缓存了多渠道信息,如果不删除会合并到当前多渠道配置
def db = new File(BASE + "jiagu.db")
if (db.exists()) {
if (!db.delete()) {
throw new RuntimeException("delete jiagu.db failure!")
}
}
exec {
commandLine "powershell", "java -jar", JAR, "-login", NAME, PASSWORD
}
exec {
commandLine "powershell", "java -jar", JAR, "-importsign", KEY_PATH, KEY_PASSWORD, ALIAS, ALIAS_PASSWORD
}
exec {
commandLine "powershell", "java -jar", JAR, "-showsign"
}
exec {
commandLine "powershell", "java -jar", JAR, "-importmulpkg", CHANNEL_CONFIG + "template_" + channel + ".txt"
}
exec {
commandLine "powershell", "java -jar", JAR, "-showmulpkg"
}
exec {
commandLine "powershell", "java -jar", JAR, "-jiagu", apk, outputPath, "-autosign", "-automulpkg"
}
}
/**
* 删除一些临时文件
* @param outputDir apk保存目录
*/
def filterApk(File outputDir) {
println "*************** filter apk ***************"
File[] files = outputDir.listFiles()
for (int i = 0; i < files.length; i++) {
File file = files[i]
String fileName = file.getName()
if (fileName.endsWith("jiagu_sign.apk") || fileName.endsWith("temp.apk")
|| !fileName.endsWith("_sign.apk")) {
file.delete()
}
}
}
/**
* 修改所有apk文件名
* @param outputDir apk保存目录
*/
def renameApk(File outputDir) {
println "*************** rename apk ***************"
File[] files = outputDir.listFiles()
for (int i = 0; i < files.length; i++) {
File file = files[i]
String fileName = file.getName()
String[] prefixArr = fileName.split("-")
String[] suffixArr = fileName.split("_")
String rename = prefixArr[0] + "-" + prefixArr[1] +
"-" + (i + 1) + "-" + suffixArr[suffixArr.length - 2] + ".apk"
file.renameTo(file.getParent() + "/" + rename)
println "rename apk: " + fileName + " --> " + rename
}
}
/**
* zip压缩apk保存目录,生成 build/outputs/release/pccb-x.x.x.zip
* @param outputDir apk保存目录
*/
def compressDir(File outputDir) {
println "*************** compress apk output dir ***************"
File zipFile = new File(outputDir.getParent() + "/" + outputDir.getName() + ".zip")
if (zipFile.exists()) {
zipFile.delete()
}
ZipOutputStream zos = new ZipOutputStream(new FileOutputStream(zipFile))
File[] files = outputDir.listFiles()
for (int i = 0; i < files.length; i++) {
File file = files[i]
byte[] bf = new byte[8192]
FileInputStream fis = new FileInputStream(file)
zos.putNextEntry(new ZipEntry(file.getName()))
int len
while ((len = fis.read(bf)) > 0) {
zos.write(bf, 0, len)
}
zos.flush()
fis.close()
}
zos.close()
}
//构建发布到生产环境的所有渠道apk,生成压缩文件 pccb-x.x.x.zip
task packageRelease {
dependsOn("assembleRelease")
doLast {
List<ApkFile> apkFiles = findApkFiles("release")
if (apkFiles.size() == 0) {
throw new RuntimeException("no apk files has found!")
}
String[] nameSlice = apkFiles.get(0).file.name.split("-")
File outputDir = new File(OUTPUT_PATH + nameSlice[0] + "-" + nameSlice[1])
if (outputDir.exists()) {
if (!outputDir.delete()) {
throw new RuntimeException("delete outputDir failure!")
}
} else {
if (!outputDir.mkdirs()) {
throw new RuntimeException("make outputDir failure!")
}
}
for (int i = 0; i < apkFiles.size(); i++) {
ApkFile apkFile = apkFiles.get(i)
reinforce(apkFile.file, outputDir.getPath(), apkFile.channel)
}
filterApk(outputDir)
renameApk(outputDir)
compressDir(outputDir)
}
}
  四. 应用pack-release.gradle
  在build.gradle顶部添加
  apply from: 'pack-release.gradle'
  jenkins配置
  1. General
  2.源码管理
  3.构建
  关于Root Build Script和Build File这里遇到了问题记录下,我前面脚本中的目录下的是 ../reinforce/,然后我在Android Studio中执行 gradlew packageRelease是没有问题的,但是在jenkins一直找不到对应的文件。后来找到原因是因为我在Android studio中是从app目录开始构建的所以没有问题,但是jenkins中是从project目录开始构建所以根本找不到对应的目录。最后通过设置 Root Build Script->app,Build File->build.gradle解决。
  4.构建后操作-归档文件

上文内容不用于商业目的,如涉及知识产权问题,请权利人联系博为峰小编(021-64471599-8017),我们将立即处理。

>>每天充电一小时,搞定Python全栈测试开发

评 论

论坛新帖

顶部 底部


建议使用IE 6.0以上浏览器,800×600以上分辨率,法律顾问:上海瀛东律师事务所 张楠律师
版权所有 上海博为峰软件技术股份有限公司 Copyright©51testing.com 2003-2019, 沪ICP备05003035号
投诉及意见反馈:webmaster@51testing.com; 业务联系:service@51testing.com 021-64471599-8017

沪公网安备 31010102002173号

51Testing官方微信

51Testing官方微博

扫一扫 测试知识全知道