空间管理您的位置: 51Testing软件测试网 » 天行健，君子以自强不息！ » 日志

少年智则国智，少年富则国富，少年强则国强，少年独立则国独立，少年自由则国自由，少年进步则国进步，少年胜于欧洲，则国胜于欧洲，少年雄于地球，则国雄于地球。红日初升，其道大光；河出伏流，一泻汪洋；潜龙腾渊，鳞爪飞扬；乳虎啸谷，百兽震惶；鹰隼试翼，风尘吸张；奇花初胎，矞矞皇皇；干将发硎，有作其芒；天戴其苍，地履其黄；纵有千古，横有八荒；前途似海，来日方长。美哉，我少年中国，与天不老！壮哉，我中国少年，与国无疆！

HP Quality Center OTA API实例 [附源码]

上一篇 / 下一篇 2009-09-25 12:39:31

查看( 1750 ) / 评论( 1 ) / 评分( 5 / 0 )

    众所周知，HP Quality Center宣称的OTA（开放式测试架构）可以实现对QC软件的完全自定义和二次开发；OTA的实现就是依赖QC强大的API接口，掌握这些API接口，企业针对QC的一切扩展想像，即可化作现实；而恰巧QC API的强大让人感觉无所不能，横扫天下！
    本文以QC9.2为蓝本，通过一个QC扩展功能的实现，来演示如何使用QC的API接口。
实例简介
    QC软件分为站点管理员和QC应用二部分，在企业使用QC的过程中，有时候一个客户端在使用QC应用的时候，会在后台的站点管理员占用二个License连接；如果你的公司QC License比较紧张，这种情况更要避免！我们能够想到的办法是在站点管理员里的Site Connections里将重复的用户连接断开，但是如果QC软件频繁发生这种情况，即便公司的QC管理员也不想随叫随到的去删除这些重复的QC连接；因此，这里我们自然想到QC宣称的无所不能的OTA API，通过编程手段自动定期删除重复连接。
前置条件

公司已经安装好Quality Center9.2服务器
本机客户端可以正常访问该服务器
本机安装Visual Basic6.0
本机具有QC站点管理员登录帐号
G7q4Z Y!i"F)\1mZ k0

实例开发

打开VB6，新建一个标准EXE程序
从VB6项目菜单里选择References，打开项目参考窗口
从项目参考窗口，找到以下二个COM组件，【SAClient Type Libray-Quality Center Site Administration】和【Microsoft XML V6.0】，并勾选它们，OK关闭该窗口
双击当前的Form1窗体，出现编程界面
拷贝以下代码到编程窗口：

Private Sub Form_Load()
    Dim QCConnection As Object
    Dim sReply As Integer
    Dim i As Integer
    Dim strCons As String
    Dim strUnavailSessions As String
    Dim arrUnavailSessions() As String
    Dim strConfig As String
    Dim arrConfig() As String

    Open "./property.conf" For Input As #3
    Line Input #3, strConfig
    Close #3
    arrConfig = Split(Trim(strConfig), ",")

    Set QCConnection = New SACLIENTLib.SAapi
    QCConnection.Login arrConfig(0), arrConfig(1), arrConfig(2)
    sReply = QCConnection.GetConnectionsCount("DEFAULT", "FlightDemo")
    strCons = Trim(QCConnection.GetConnections)

    Open "./qcconnections.xml" For Output As #1
    Print #1, Trim(strCons)
    Close #1

    Open "./QCLicenseCleanUp.log" For Append As #2
    Print #2, "**************************************************************************"
    Print #2, "作者：叶赫华运行时间:" & Now()
    Print #2, "当前QC服务器共有" & CStr(sReply) & "个连接."

    strUnavailSessions = GetQCUnavailSessions("./qcconnections.xml")
    arrUnavailSessions = Split(strUnavailSessions, ",")

    If Trim(strUnavailSessions) = ":" Then
        Print #2, "没有重复的连接需要断开！"
    Else
        Print #2, "开始在叶赫华本机清理重复连接..."
        For i = 0 To UBound(arrUnavailSessions)
            QCConnection.Disconnect CLng(Split(arrUnavailSessions(i), ":")(0))
            Print #2, "删除重复连接[SessionID:UserName] [" & arrUnavailSessions(i) & "] 成功..."
        Next
        Print #2, "连接清理完毕!"
    End If

    Print #2, "作者：叶赫华结束时间:" & Now()
    Print #2, "**************************************************************************"
    Print #2,
    Close #2
    Set QCConnection = Nothing
    End
End Sub

Public Function GetQCUnavailSessions(strConFilePath As String) As String
    Dim arrSessionId() As String
    Dim arrUserName() As String
    Dim arrLastAction() As String
    Dim arrDeleteSessions() As String
    Dim strReturn As String
    Dim delCount As Integer
    Dim userCount As Integer
    delCount = 0
    userCount = 0

    Dim objDOMDoc As New DOMDocument60
    objDOMDoc.async = False
    objDOMDoc.Load strConFilePath

    Dim root As MSXML2.IXMLDOMElement
    Set root = objDOMDoc.documentElement

    Dim sessionIdList As MSXML2.IXMLDOMNodeList
    Set sessionIdList = root.selectNodes("/GetConnections/TDXItem/LOGIN_SESSION_ID")
    Dim userNameList As MSXML2.IXMLDOMNodeList
    Set userNameList = root.selectNodes("/GetConnections/TDXItem/USERNAME")
    Dim lastActionList As MSXML2.IXMLDOMNodeList
    Set lastActionList = root.selectNodes("/GetConnections/TDXItem/LASTACTION")

    Dim length As Integer
    length = sessionIdList.length - 1

    ReDim arrSessionId(length)
    ReDim arrUserName(length)
    ReDim arrLastAction(length)
    ReDim arrDeleteSessions(length)
    ReDim arrDeleteUserName(length)

    Dim i As Integer
    Dim j As Integer
    Dim flag As Boolean

    For i = 0 To length
        flag = False
        For j = 0 To userCount
            If userNameList(i).Text = arrUserName(j) Then
                flag = True
                If lastActionList(i).Text > arrLastAction(j) Then
                    arrDeleteSessions(delCount) = arrSessionId(j)
                    arrDeleteUserName(delCount) = arrUserName(j)
                    arrSessionId(j) = sessionIdList(i).Text
                    arrLastAction(j) = lastActionList(i).Text
                Else
                    arrDeleteSessions(delCount) = sessionIdList(i).Text
                    arrDeleteUserName(delCount) = userNameList(i).Text
                End If
                delCount = delCount + 1
                Exit For
            End If
        Next

        If flag = False Then
            arrSessionId(userCount) = sessionIdList(i).Text
            arrLastAction(userCount) = lastActionList(i).Text
            arrUserName(userCount) = userNameList(i).Text
            userCount = userCount + 1
        End If
    Next

    strReturn = arrDeleteSessions(0) + ":" + arrDeleteUserName(0)
    For i = 1 To delCount - 1
        strReturn = strReturn + "," + arrDeleteSessions(i) + ":" + arrDeleteUserName(i)
    Next

    Set sessionIdList = Nothing
    Set userNameList = Nothing
    Set lastActionList = Nothing
    Set root = Nothing
    Set bjDOMDoc = Nothing
    GetQCUnavailSessions = strReturn
End Function

    6.选择VB6文件菜单，Make该EXE应用程序到本机D:\SinckyQC\QCLicenseCleanUp.exe文件夹下
    7.关闭VB6
    8.在D:\SinckyQC目录下新建一个文本文件，输入一行内容：http://[QCServerName]:8080/sabin,[QC Site Admin username],[QC Site Admin password]，并保存该文件，名为property.conf
    9.双击QCLicenseCleanUp.exe运行即可；如果出错，请打开VB6去调试，直到成功
    10.在该文件夹下检查出现的QCLicenseCleanUp.log文件，打开显示类似如下内容：
**************************************************************************
作者：叶赫华运行时间:9/1/2009 11:46:05 AM
当前QC服务器共有14个连接
开始在叶赫华本机清理重复连接...
删除重复连接[SessionID:UserName] [39390:sincky.zhang] 成功...
删除重复连接[SessionID:UserName] [39326:hehua.ye] 成功...
连接清理完毕!
作者：叶赫华结束时间:9/1/2009 11:46:23 AM
**************************************************************************
【完】     叶赫华       2009年9月     上海       MSN: SINCKYZHANG@GMAIL.COM

Link URL: http://sinckyzhang.blog.sohu.com/130888193.html

收藏举报

TAG:

引用删除 violet0214 / 2012-07-02 17:13:58: 评 5 分

查看全部评论

HP Quality Center OTA API实例 [附源码]

用户菜单

我的栏目

标题搜索

日历

我的存档

数据统计

RSS订阅