Perl语言入门学习笔记-7
上一篇 / 下一篇 2007-09-05 11:14:08 / 个人分类：编程吧
正则表达式与文本处理
+文本替换
++替换（substitution）操作符: s///
s/pattern1/pattern2/
对pattern1进行模式匹配，如果成功，将pattern1替换成pattern2，s///返回值为真，如果失败，什么事也不会发生，s///返回值为假。
例子：
$_="green scaly dinosaur";
s/(\w+) (\w+)/$2, $1/; #"scaly, green dinosaur
s/^/huge, /; #"huge, scaly, green dinosaur"
s/,.*een//; #"huge dinosaur"
s/green/red/; #匹配失败，不变
s/\w+$/($`!)$&/; #"huge (huge !)dinosaur"
s/\s+(!\W+)/$1 /; #"huge (huge!) dinosaur"
++全局替换
/g修饰符：将所有的匹配进行替换
s/\s+/ /g #缩减空白，将所有连续的空白转换成单一空格
s/^\s+// #将开头的空白转换成空字符串
s/\s+$// #将结尾的空白转换成空字符串
s/^\s+|\s+$//g
/g也可以用于m//操作符，可以让模式匹配到字符串中的多个地方。
其他修饰符：/i，/s，含义同前
s{__END__.*}{}s #删除结尾标记及之后的每一行
++不同的界定符
对于没有左右之分的界定符，用法同斜线/。
对于有左右之分的成对界定符，必须使用两对：一对包住模式，一对包住替换字符串。这两对不需要相同。
s{fred}{barney}
s<fred>#barney#
$file_name=~s#^.*/##s; #移除$file_name中所有Unix样式的路径
++大小写转换（放在替换字符串前，也适用于任何双引号内的字符串）
\U转义字符会将其后所有的字符转换成大写
\L转义字符会将其后所有的字符转换成小写
\E转义字符关闭大小写转换功能
\u、\l只影响之后的第一个字符
例子：
$_="I saw Barney with Fred.";
s/(fred|barney)/\U$1/gi; #"I saw BARNEY with FRED."
s/(fred|barney)/\L$1/gi; #"I saw barney with fred."
s/(\w+) with (\w+)/\U$2\E with $1/i;
#"I saw FRED with barney."
s/(fred|barney)/\u$1/ig; #"I saw FRED with Barney."
s/(fred|barney)/\u\L$1/ig; #"I saw Fred with Barney."
++split操作符
用法：@fields=split /separator/,$string
split操作符以作为分隔符的模式扫过指定字符串（将字符串进行分割），返回由该模式分隔的各字段组成的列表。
模式在某处匹配成功，该处即为一个字段的结尾，下一个字段的开头，模式（分隔符）本身不包含在字段中。
@field=split /:/,":::a:b:c:::"; #("","","","a","b","c")
#split会保留开头的空字段，而舍弃结尾的空字段。
#如果想保留结尾的空字段，以-l作为split的第三个参数
my $some_input="This is a \t test.\n";
my @args=split /\s+/,$some_input;
#("This","is","a","test.")
#利用模式/\s+/进行分割，所有空白被当作一个空格来处理
my @fields=split;
#等于split /\s+/,$_;，但开头的空字段会被忽略
my @fields=split ' ',$other_string;
#用一个空格来代替模式，是split的特别用法
++join函数
join没有用到模式（split的第一个参数是模式，join的第一个参数是字符串），效果与split相反，会将若干个字段合并成一个字符串。
用法：my $result=join $glue,@pieces;
my $x=join ":",4,6,8,10; #$x="4:6:8:10
$glue的数目比@piece列表中的数目少1，列表中至少有两个元素，否则$glue将不会出现。
++列表上下文中的m//
在列表上下文中使用模式匹配操作符，如果匹配成功，则返回的列表内容是所有匹配变量的内容，否则返回空列表。
$_="Hello there, neighbor!";
my($first,$second,$third)=/(\S+) (\S+), (\S+)/;
print "$second is my $third\n";
my $text="Fred dropped a 5 ton granite block on Mr. Slate";
my @words=($text=~/([a-z]+)/ig);
#每次成功匹配都返回一个记忆（对应一对圆括号）
print "Result: @words\n";
#Result: Fred dropped a ton granite block on Mr Slate
my $data="Barney Rubble Fred Flintstone Wilma Flintstone";
my %last_name=($data=~/(\w+)\s+(\w+)/g); ##每次成功匹配都返回一对记忆
+更高级的主题
++非贪心的量词
贪心(greedy)量词：匹配时这些量词（*、+、?、{n,m}）会尽量匹配长字符串。
正则表达式引擎的回溯（backtracking）算法:
以/fred.+barney/匹配fred and barney went bowling last night为例
1. 先找到fred
2. 匹配.+时，先匹配剩下的所有字符 #贪心嘛
3. 匹配barney时，如果不匹配，.+模式放弃一个字符，再检查是否匹配barney
4. 继续进行第3步操作直到匹配成功
非贪心的量词：
+? 至少匹配一次，但匹配到的字符串越短越好。
再以/fred.+?barney/匹配fred and barney went bowling last night为例
1. 先找到fred
2. 匹配.+?时，先匹配一个非\n字符 #太清廉了！
3. 匹配barney时，如果不匹配，.+?模式加一个字符，再检查是否匹配barney
4. 继续进行第3步操作直到匹配成功
正则表达式引擎处理的速度取决于处理的数据。
同样的，有*？、??、{n,m}?、{n,}?
++多行的模式匹配
m/pattern/m
模式加上/m修饰符后，锚点^、$代表的位置变为多行字符串每行的开头和结尾。
open FILE, $filename
or die "Can't open '$filename': $!";
my $lines=join '', <FILE>;
#将整个文件的内容读入一个变量，该文件不能太大
$lines=~s/^/$filename: /gm
#将文件名前置于每行开头
++一次更新多个文件
假设有几百个格式类似的数据文件fred*.dat，它们有如下内容：
Program name: ...
Author: ...
Company: ...
Department: ...
Phone: ...
Date: ...
Version: ...
Size: ...
Status: ...
现在要将Author字段统一成一个人，Date字段更新到系统最新时间，删除Phone字段。
#!/usr/bin/perl -w
use strict;
chomp(my $date=`date`);
#或者在标量上下文中使用Perl的localtime函数
#my $date=localtime;
$^I=".bak";
while(<>) {
s/^Author:.*/Author: Randal Schwartz/;
s/^Phone:.*\n//;
s/^Date:.*/Date: $date/;
print;
}
变量$^I：默认值undef，当被赋值为某个字符串时，该字符串会变为备份文件的扩展名。注意：是大写的"AI"，不是小写的"l"。
钻石操作符<>在打开某个数据文件，例如fred03.dat时，会将其改名为fred.dat.bak做备份。然后<>再打开一个新文件并将其命名为fred03.dat，<>也会试图复制源文件的属主和使用权限，同时将默认输出设定为这个新打开的文件。那么所有输出的内容就写入这个新文件中。
while循环从旧文件中读入一行，作相应改动后，再将新内容写入新文件中。原来的文件没有被改动。
$^I=~; #emacs处理备份文件文件名的方式
$^I=''; #警告！会直接修改源文件的内容。
++只从命令行来修改文件
perl的选项：
-p: 相当于写了个小程序，类似于
while(<>) {
print;
}
-n: 相当于写了个小程序，类似于
while(<>) {
#去掉了print
}
-i: 设置$^I，-i.bak,如果不想做备份，直接写-i。
-w: 开启警告功能
-e: 程序代码来了！其后的代码将放在while循环中，print之前，可以省略结尾的分号。
如果指定了多个-e选项，就有多段代码，只有最后一行结尾的分号可以省略。
$ perl -p -i.bak -w -e 's/Randall/Randal/g' fred*.dat
#这个命令行等价于下面的程序代码
#!/usr/bin/perl -w
$^I=.bak;
while(<>) {
s/Randall/Randal/g;
print;
}
++不具记忆功能的圆括号（non-capturing parentheses）
(?:...) #这对圆括号只用来分组，没有记忆功能
Perl按照左括号的顺序决定对应内存变量的名称。比较下面的两段代码，只查询steak或burger模式：
if(/(bronto)?saurus (BBQ )?(steak|burger)/) {
print "Fred wants a $3\n";
}
if(/(?:bronto)?saurus (?:BBQ )?(steak|burger)/) {
print "Fred wants a $1\n";
}
谢天谢地！正则表达式可以告一段落了！庆祝一下！
习题4、5
#!/usr/bin/perl -w
use strict;
$^I=".bak";
while (<>) {
if (/copyright \(C\)/i) {
next;
}
s/^(\#!.*\n)/$1\#\# Copyright \(C\) 20XX by Sophia Wan\n/;
print;
}
相关阅读:
- Perl语言入门学习笔记-0 (donghua_wan, 2007-8-20)
- Perl语言入门学习笔记-1 (donghua_wan, 2007-8-21)
- Perl语言入门学习笔记-2 (donghua_wan, 2007-8-24)
- Perl语言入门学习笔记-3 (donghua_wan, 2007-8-27)
- Perl语言入门学习笔记-4 (donghua_wan, 2007-8-30)
- Perl语言入门学习笔记-5 (donghua_wan, 2007-8-31)
- Perl语言入门学习笔记-6 (donghua_wan, 2007-9-03)
TAG: 编程吧
标题搜索
日历
|
|||||||||
| 日 | 一 | 二 | 三 | 四 | 五 | 六 | |||
| 1 | 2 | 3 | 4 | 5 | 6 | ||||
| 7 | 8 | 9 | 10 | 11 | 12 | 13 | |||
| 14 | 15 | 16 | 17 | 18 | 19 | 20 | |||
| 21 | 22 | 23 | 24 | 25 | 26 | 27 | |||
| 28 | 29 | 30 | |||||||
数据统计
- 访问量: 22385
- 日志数: 38
- 文件数: 1
- 书签数: 3
- 建立时间: 2007-08-14
- 更新时间: 2008-05-01
